Kullanisli Fonksiyonlar

[Skyline.]

Ryder program özel değilse banada atabilir misin?

[Skyline.]

Ryder program özel değilse banada atabilir misin?

Edit:
XpDevil şuranının

Kod: [Seç]

stock set(dest[],source[]) {
   new count = strlen(source);
   new i=0;
   for (i=0;i<count;i++) {
      dest=source;
   }
   dest[count]=0;
}şöyle olması gerekmiyor mu?

Kod: [Seç]

stock set(dest[],source[]) {
   new count = strlen(source);
   new i=0;
   for (i=0;i<count;i++) {
      dest[i]=source[i];
   }
   dest[count]=0;
}


[RyDeR`]

Bilgi (returnOrdinal) (yeni)
Bir numaranin inglizcedeki sira sayisini verir.

Code

stock returnOrdinal(number)
{
   new
       ordinal[4][3] = { "st", "nd", "rd", "th" }
   ;
   number = number < 0 ? -number : number;
   return (((10 < (number % 100) < 14)) ? ordinal[3] : (0 < (number % 10) < 4) ? ordinal[((number % 10) - 1)] : ordinal[3]);
}

Örnek

printf("%s", returnOrdinal(3));

Sonuc olarak:

"rd"

verir..

Not: Bu kod bu önceki yazdigim kodun güncellemesidir.

[RyDeR`]

Bilgi (DeletePlayerWeapon)
Diger silahlara ellemeden bir silahi yok eder.

Code

stock DeletePlayerWeapon(playerid, weaponid)
{
    new
        gWeaponData[13][2]
    ;
   
    for(new i; i != sizeof(gWeaponData); ++i)
    {
        GetPlayerWeaponData(playerid, i, gWeaponData[i][0], gWeaponData[i][1]);
       
        gWeaponData[i][1] = gWeaponData[i][1] < 0 ? -gWeaponData[i][1] : gWeaponData[i][1];
    }
    ResetPlayerWeapons(playerid);

    for(new i; i != sizeof(gWeaponData); ++i)
    {
        if(gWeaponData[i][0] != weaponid)
        {
            GivePlayerWeapon(playerid, gWeaponData[i][0], gWeaponData[i][1]);
        }
    }
    return 1;
}

Örnek

DeletePlayerWeapon(playerid, 28);

Bu oyuncunun digerlerine ellemeden 28 ID'li silahini siler.

[RyDeR`]

toUpper
Bir karakteri buyuk harf yapar.

stock toUpper(c)
{
    return ('a' <= c <= 'z') ? (c += 'A' - 'a') : (c);
}

isCharUpper
Bir karakter buyuk harf ise degeri 1 verir, degilse 0.

stock isCharUpper(c)
{
   return ('A' <= c <= 'Z');
}

toLower
Bir karakteri kucuk harf yapar.

stock toLower(c)
{
   return ('A' <= c <= 'Z') ? (c += 'a' - 'A') : (c);
}

isCharLower
Bir karakter kucuk harf ise degeri 1 verir degilse 0.

stock isCharLower(c)
{
   return ('a' <= c <= 'z');
}

[RyDeR`]

Bilgi (arraySort)
Bir array icindeki numaralari kücükten büyüge (1) veya büyükten kücüge (0) siralar.

Code

stock arraySort(num[], smalltobig, size = sizeof(num))
{
    new
        tempVar
    ;
    for(new x; x != size; ++x)
    {
        tempVar = num[x];
       
        for(new y = x - 1; y > -1; --y)
        {
            if((!smalltobig) ? (tempVar > num[y]) : (tempVar < num[y]))
            {
                num[y] ^= num[y + 1], num[y + 1] ^= num[y], num[y] ^= num[y + 1];
            }
        }
    }
    return 1;
}

Örnek
Örnek olarak, kücükten büyüge:

new
    num[] =
    {
        311,
        4237,
        3405,
        4367,
        642,
        227,
        3677,
        4319,
        3675,
        2407,
    }
;
arraySort(num, 1);

Array'i su sekilde düzenler:

227
311
642
2407
3405
3675
3677
4237
4319
4367

Baska bir örnek, büyükten kücüge:

new
    num[] =
    {
        311,
        4237,
        3405,
        4367,
        642,
        227,
        3677,
        4319,
        3675,
        2407,
    }
;
arraySort(num, 0);

Array'i su sekilde düzenler:

4367
4319
4237
3677
3675
3405
2407
642
311
227

[XpDeviL]

Bilgi (returnNameSwear)
Kişinin İsmini "strdel" Functionu kullanarak belirli karakterini siler.

Code:

Kod: [Seç]

stock returnNameSwear(playerid,start,end)
{
new
    pName[MAX_PLAYER_NAME];
GetPlayerName(playerid,pName,sizeof(pName));
strdel(pName,start,end);
SetPlayerName(playerid,pName);
return 1;
}
Örnek:

Kod: [Seç]

if(strcmp(cmd,"/nameswear",true)==0)
{
new tmp[256];
tmp = strtok(cmdtext,idx);
if(!strlen(tmp)) return SendClientMessage(playerid,0xFFAABB0,"[KULLANIM] /nameswear [id] [start] [end]");
new id = strval(tmp);
if(!IsPlayerConnected(id)) return SendClientMessage(playerid,0xFFAABB0,"Yanlış id!");
tmp = strtok(cmdtext,idx);
if(!strlen(tmp)) return SendClientMessage(playerid,0xFFAABB0,"[KULLANIM] /nameswear [id] [start] [end]");
new start = strval(tmp);
if(start > MAX_PLAYER_NAME) return SendClientMessage(playerid,0xFFAABB0,"Karakter Çok Büyük!");
tmp = strtok(cmdtext,idx);
if(!strlen(tmp)) return SendClientMessage(playerid,0xFFAABB0,"[KULLANIM] /nameswear [id] [start] [end]");
new end = strval(tmp);
if(start > MAX_PLAYER_NAME) return SendClientMessage(playerid,0xFFAABB0,"Karakter Çok Büyük!");
returnNameSwear(id,start,end);
return 1;
}
Mesela : /nameswear 1 0 3

id 1 in adı Gerizekağlı bu komutu ona uygulanınca ismi ; izekağlı oluyor.

[RyDeR`]

Bilgi (sortWords)
Kelimeleri A'dan Z'ye veya Z'den A'ya siralar. (secenege bagli)

Code

stock sortWords(words[][], A_to_Z, size = sizeof(words))
{
    for(new x; x != size - 1; ++x)
    {
        for(new y = x; y != size; ++y)
        {
            if((!A_to_Z) ? (strcmp(words[x], words[y]) < 0) : (strcmp(words[x], words[y]) > 0))
            {
                new
                    string[16]
                ;
                format(string, sizeof(string), words[x]);
                format(words[x], sizeof(string), words[y]);
                format(words[y], sizeof(string), string);
            }
        }
    }
    return 1;
}

Örnek
Mesela array icindeki kelimeleri A'den Z'ye siraliyalim (secenek 1):

new
    names[][16] =
    {
        "Benjamin",
        "Andreas",
        "Ryan",
        "Jason",
        "Michael",
        "Brad",
        "Dean",
        "Thomas",
        "Alex",
        "Ashley",
        "Lovely",
        "Carl",
        "Johnattan",
        "Macy",
        "Vanessa",
        "Eddy",
        "Curtis",
        "Alan",
        "Lacy",
        "Faith",
        "Dianna",
        "Esmee",
        "Glenn",
        "Jordy",
        "Yasmin",
        "Tracy",
        "Zena",
        "Wendy"
      }
;
sortWords(names, 1);
   
for(new i; i != sizeof(names); ++i)
{
    printf("%s", names[i]);
}

Sonuc:

Alan
Alex
Andreas
Ashley
Benjamin
Brad
Carl
Curtis
Dean
Dianna
Eddy
Esmee
Faith
Glenn
Jason
Johnattan
Jordy
Lacy
Lovely
Macy
Michael
Ryan
Thomas
Tracy
Vanessa
Wendy
Yasmin
Zena

Z'den A ile sonuc (secenek 0):

Zena
Yasmin
Wendy
Vanessa
Tracy
Thomas
Ryan
Michael
Macy
Lovely
Lacy
Jordy
Johnattan
Jason
Glenn
Faith
Esmee
Eddy
Dianna
Dean
Curtis
Carl
Brad
Benjamin
Ashley
Andreas
Alex
Alan

[RyDeR`]

Bilgi
2 boyut veya 3 boyut Nokta(lar) arasindaki mesafeyi bulur.

Code

stock distanceBetweenPoints2D(Float: x1, Float: y1, Float: x2, Float: y2)
{
   return _: (floatsqroot((floatpower(floatabs((x2 - x1)), 2)) + floatpower(floatabs((y1 - y2)), 2)));
}

stock distanceBetweenPoints3D(Float: x1, Float: y1, Float: z1, Float: x2, Float: y2, Float: z2)
{
   return _: (floatsqroot((floatpower(floatabs((x2 - x1)), 2) + floatpower(floatabs((y2 - y1)), 2) + floatpower(floatabs((z2 - z1)), 2))));
}

Örnek
Bu sefer örnek bir kod eklemedim cünkü normalda hersey acik.

[RyDeR`]

Fonksiyon istekleri varmi? Varsa lütfen buryaya yazin. Zamanim olunca yapip paylasirim.

[AyDooGii]

Fonksiyon istekleri varmi? Varsa lütfen buryaya yazin. Zamanim olunca yapip paylasirim.

Bana bi kod yapabilirmisin sureli spawn fakat dialog stil list lerdede etkili olacak??? Teşekkürler

[RyDeR`]

Bana bi kod yapabilirmisin sureli spawn fakat dialog stil list lerdede etkili olacak??? Teşekkürler

O istedigin fonksiyon degil ki ^^

[RyDeR`]

Baska fonksiyon paylasan yokmu?

Bu arada istekler varsa yazin, yapip paylasirim.

[L3G0L4S]

O kadar çok ki aklıma fonksiyon gelmiyor.

[RyDeR`]

Baska fonksiyon paylasan yokmu?

Bu arada istekler varsa yazin.

Sinavlar bitince yazip paylasirim.